project(libssh C)

# Required cmake version
cmake_minimum_required(VERSION 2.8.5)

# global needed variables
set(APPLICATION_NAME ${PROJECT_NAME})

set(APPLICATION_VERSION_MAJOR "0")
set(APPLICATION_VERSION_MINOR "7")
set(APPLICATION_VERSION_PATCH "90")

set(APPLICATION_VERSION "${APPLICATION_VERSION_MAJOR}.${APPLICATION_VERSION_MINOR}.${APPLICATION_VERSION_PATCH}")

# SOVERSION scheme: CURRENT.AGE.REVISION
#   If there was an incompatible interface change:
#     Increment CURRENT. Set AGE and REVISION to 0
#   If there was a compatible interface change:
#     Increment AGE. Set REVISION to 0
#   If the source code was changed, but there were no interface changes:
#     Increment REVISION.
set(LIBRARY_VERSION "4.5.0")
set(LIBRARY_SOVERSION "4")

# where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
set(CMAKE_MODULE_PATH
  ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules
)

# add definitions
include(DefineCMakeDefaults)
include(DefinePlatformDefaults)
include(DefineCompilerFlags)
include(DefineInstallationPaths)
include(DefineOptions.cmake)
include(CPackConfig.cmake)

# disallow in-source build
include(MacroEnsureOutOfSourceBuild)
macro_ensure_out_of_source_build("${PROJECT_NAME} requires an out of source build. Please create a separate build directory and run 'cmake /path/to/${PROJECT_NAME} [options]' there.")

set(CMAKE_CONFIGURATION_TYPES "Debug;Release")
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
set(CMAKE_INSTALL_RPATH "$ORIGIN")
set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
set(CMAKE_C_VISIBILITY_PRESET hidden)
set(CMAKE_CXX_VISIBILITY_PRESET hidden)

if(LIBSSH_MBEDTLS_FROM_SOURCE)
	if (WIN32)
		set(SWX_OUTPUT_PATH "${CMAKE_CURRENT_LIST_DIR}/../../../Binary/VS2008/Output")

		get_filename_component(SWX_OUTPUT_PATH ${SWX_OUTPUT_PATH} ABSOLUTE)

		if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsCE")
			string(APPEND SWX_OUTPUT_PATH "/supersonic_ce6 (armv4i)")
		else()
			string(APPEND SWX_OUTPUT_PATH "/Win32")
		endif()

		string(APPEND SWX_OUTPUT_PATH "/$<IF:$<CONFIG:Debug>,Debug,Release>")

		set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${SWX_OUTPUT_PATH})
		set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${SWX_OUTPUT_PATH})
		set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${SWX_OUTPUT_PATH})

		# Debug outputs will have a "d" appended.
		set(CMAKE_DEBUG_POSTFIX d)
	endif()
endif()

if (WIN32)
	# Add common project settings, satisfy CheckProjectSettings
	add_compile_options(/Zi /Zc:wchar_t /GR /EHa /fp:strict /fp:except-)
	
	#add_compile_options(/Za /J /Zc:forScope-)
	
	# Character set of VS project is UNICODE
	add_definitions("/D_UNICODE /DUNICODE")
	
	# Forced include
	add_compile_options(/FI"wincompat.h")
	
	if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsCE")
		# Remove some flags set in DefineCompilerFlags
		string(REPLACE "/D _CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES=1" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
		string(REPLACE "/D _CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES_COUNT=1" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
		
		# Replace some default compiler settings
		string(REPLACE "/D_WIN32_WCE=0x600" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
		string(REPLACE "/DARMV4I" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
		string(REPLACE "/D_WINDOWS" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
		string(REPLACE "/QRarch4T" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
		# Set new values, set CMAKE_C_FLAGS directly
		# add_compile_options does not work for configuration checks
		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /D_WIN32_WCE=$(CEVER) /DHW_ARM /DPLAT_WINCE_ARM /DOS_WINCE")
		
		# Use mainCRTStartup (ASCII main) instead of mainWCRTStartup (UNICODE main)
		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /ENTRY:mainCRTStartup")
		
		add_compile_options(/QRarch6)
	endif()
	
	# Release build linker optimizations and generate debug symbols
	set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /DEBUG /OPT:REF /OPT:NOICF")
endif()

# search for libraries
if (WITH_ZLIB)
    find_package(ZLIB REQUIRED)
endif (WITH_ZLIB)

if (WITH_GCRYPT)
  find_package(GCrypt 1.5.0 REQUIRED)
  if (NOT GCRYPT_FOUND)
    message(FATAL_ERROR "Could not find GCrypt")
  endif (NOT GCRYPT_FOUND)
elseif(WITH_MBEDTLS)
  # Just set to directories to make find_package MbedTLS succeed
  set(MBEDTLS_INCLUDE_DIR "${CMAKE_CURRENT_LIST_DIR}/../../mbedtls/include")
  if(LIBSSH_MBEDTLS_FROM_SOURCE)
    set(MBEDTLS_CRYPTO_LIBRARY "${CMAKE_CURRENT_LIST_DIR}/../../../Binary")
    set(MBEDTLS_SSL_LIBRARY "${CMAKE_CURRENT_LIST_DIR}/../../../Binary")
    set(MBEDTLS_X509_LIBRARY "${CMAKE_CURRENT_LIST_DIR}/../../../Binary")
    find_package(MbedTLS REQUIRED)
  else()
    set(MBEDTLS_CRYPTO_LIBRARY 3rdparty::MBedTls)
  endif()

  if (NOT MBEDTLS_FOUND)
    message(FATAL_ERROR "Could not find mbedTLS")
  endif (NOT MBEDTLS_FOUND)
else (WITH_GCRYPT)
  find_package(OpenSSL)
  if (NOT OPENSSL_FOUND)
    find_package(GCrypt)
    if (NOT GCRYPT_FOUND)
      find_package(MbedTLS)
      if (NOT MBEDTLS_FOUND)
        message(FATAL_ERROR "Could not find OpenSSL, GCrypt or mbedTLS")
      endif (NOT MBEDTLS_FOUND)
    endif (NOT GCRYPT_FOUND)
  endif (NOT OPENSSL_FOUND)
endif(WITH_GCRYPT)

# Find out if we have threading available
set(CMAKE_THREAD_PREFER_PTHREADS ON)
find_package(Threads)

if (WITH_GSSAPI)
    find_package(GSSAPI)
endif (WITH_GSSAPI)

if (WITH_NACL)
    find_package(NaCl)
    if (NOT NACL_FOUND)
        set(WITH_NACL OFF)
    endif (NOT NACL_FOUND)
endif (WITH_NACL)

if (BSD OR SOLARIS OR OSX)
    find_package(Argp)
endif (BSD OR SOLARIS OR OSX)

# config.h checks
include(ConfigureChecks.cmake)

# Override some results from ConfigureChecks for CE
if ("${CMAKE_SYSTEM_NAME}" STREQUAL "WindowsCE")
	set(HAVE_MSC_THREAD_LOCAL_STORAGE 0)
	set(HAVE_IO_H 1)
	# ConfigureChecks uses set(CMAKE_REQUIRED_LIBRARIES ws2_32) which will not work for CE
	set(HAVE_SELECT 1)
	set(HAVE_GETADDRINFO 1)
endif()

configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# check subdirectories
add_subdirectory(doc)
add_subdirectory(include)
add_subdirectory(src)

# pkg-config file
if (UNIX)
configure_file(libssh.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/libssh.pc)
install(
  FILES
    ${CMAKE_CURRENT_BINARY_DIR}/libssh.pc
    ${CMAKE_CURRENT_BINARY_DIR}/libssh_threads.pc
  DESTINATION
    ${LIB_INSTALL_DIR}/pkgconfig
  COMPONENT
    pkgconfig
)

    if (LIBSSH_THREADS)
        configure_file(libssh_threads.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/libssh_threads.pc)
        install(
          FILES
            ${CMAKE_CURRENT_BINARY_DIR}/libssh.pc
            ${CMAKE_CURRENT_BINARY_DIR}/libssh_threads.pc
          DESTINATION
            ${LIB_INSTALL_DIR}/pkgconfig
          COMPONENT
            pkgconfig
        )
    endif (LIBSSH_THREADS)
endif (UNIX)

# cmake config files
set(LIBSSH_LIBRARY_NAME ${CMAKE_SHARED_LIBRARY_PREFIX}ssh${CMAKE_SHARED_LIBRARY_SUFFIX})
set(LIBSSH_THREADS_LIBRARY_NAME ${CMAKE_SHARED_LIBRARY_PREFIX}ssh${CMAKE_SHARED_LIBRARY_SUFFIX})

configure_file(${PROJECT_NAME}-config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake @ONLY)
configure_file(${PROJECT_NAME}-config-version.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake @ONLY)
install(
    FILES
        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake
    DESTINATION
        ${CMAKE_INSTALL_DIR}/${PROJECT_NAME}
    COMPONENT
        devel
)


# in tree build settings
configure_file(libssh-build-tree-settings.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/libssh-build-tree-settings.cmake @ONLY)

if (WITH_EXAMPLES)
    add_subdirectory(examples)
endif (WITH_EXAMPLES)

if (WITH_TESTING)
  find_package(CMocka REQUIRED)
  include(AddCMockaTest)
  add_subdirectory(tests)
endif (WITH_TESTING)


message(STATUS "********************************************")
message(STATUS "********** ${PROJECT_NAME} build options : **********")

message(STATUS "zlib support: ${WITH_ZLIB}")
message(STATUS "libgcrypt support: ${WITH_GCRYPT}")
message(STATUS "libmbedTLS support: ${WITH_MBEDTLS}")
message(STATUS "libnacl support: ${WITH_NACL}")
message(STATUS "SSH-1 support: ${WITH_SSH1}")
message(STATUS "SFTP support: ${WITH_SFTP}")
message(STATUS "Server support : ${WITH_SERVER}")
message(STATUS "GSSAPI support : ${WITH_GSSAPI}")
message(STATUS "Pcap debugging support : ${WITH_PCAP}")
message(STATUS "With static library: ${WITH_STATIC_LIB}")
message(STATUS "Unit testing: ${WITH_TESTING}")
message(STATUS "Client code Unit testing: ${WITH_CLIENT_TESTING}")
if (WITH_INTERNAL_DOC)
    message(STATUS "Internal documentation generation")
else (WITH_INTERNAL_DOC)
    message(STATUS "Public API documentation generation")
endif (WITH_INTERNAL_DOC)
message(STATUS "Benchmarks: ${WITH_BENCHMARKS}")
message(STATUS "********************************************")

